Writing a Program (Standard Files)

CA Datacom/DB Reporting Facility Tutorial › Writing a Program (Standard Files)

Writing a Program (Standard Files)

If you use the Reporting Facility to access standard files, practice writing a program that accesses a standard file. This section presents the requirements of a report and then provides the program that generated it. The report generated by the program you write has the following format:

XYZ COMPANY, INC. 01 NOV 08 EARNINGS REPORT PAGE 1 DEPT EMPLOYEE EMPLOYEE REGULAR OVERTIME NUMBER NUMBER NAME EARNINGS EARNINGS XXX XXXX XXXXXXXXXXXXXXXXXXXX XXX.XX XXX.XX . . . . . . . . . . . . . . . XXX XXXX XXXXXXXXXXXXXXXXXXXX XXX.XX XXX.XX _______ GRAND TOTAL XXXXX.XX ________

This format indicates that the program will generate a report that includes:

Specified headings
Department number
Employee number
Employee name
Regular earnings
Overtime earnings
Grand total for overtime earnings

The following are the position and contents of the input record fields:

1-3: Department number
4-7: Employee number
8-27: Employee name
28-29: Hours
30-33: Current rate (9.999)
34-38: Regular earnings (999.99)
39-43: Overtime earnings (999.99)

In writing the program, make the following assumptions:

The accessed file is a standard sequential disk file.
The file name is PAYFILE.
Each record on the file is 43 bytes long.
Each block of data on the disk file contains 50 records.
The department number field is PAYFILE-DEPTNUM.
The employee number field is PAYFILE-EMPNUM.
The employee name field is PAYFILE-NAME.
The regular earnings field is named PAYFILE-REGEARN.
The overtime earnings field is named PAYFILE-OVTEARN.
The report is sorted in ascending sequence by department number.

Note: You may also assume that all of the fields defined with a DEFINE statement are alphanumeric, except the regular earnings and overtime earnings fields, which are numeric with two implied decimal places.

Remember that you would provide the requirements (as shown previously) in a real situation. Study the command formats and note which parameters are commands or reserved words and which parameters you must supply.

There are three significant differences between the earnings report program in this section and the earnings report program in the previous section.

The program in this section requires a standard file definition.
There is no Communications Area in this program because the file is standard.
The program in this section requires a grand total for the overtime earnings field. The grand total is specified with the PRINT command.

After you have written the program, check the following solution to find the correct input statements and their explanations. .

Solution

USER 'XYZ COMPANY, INC.' PAYFILE: INPUT DISK BLOCK EQ 2150 FIXED RECORD EQ 43 DEFINE PAYFILE-DEPTNUM 001-003 X ' DEPT ' 'NUMBER' DEFINE PAYFILE-EMPNUM 004-007 X 'EMPLOYEE' 'NUMBER' 'NUMBER' DEFINE PAYFILE-NAME 008-027 X 'EMPLOYEE' ' NAME ' DEFINE PAYFILE-REGEARN 034-038 N2 'REGULAR' 'EARNINGS' DEFINE PAYFILE-OVTEARN 039-043 N2 'OVERTIME' 'EARNINGS' GET PAYFILE GOTO EOJ WHEN PAYFILE EQ 'E' REPORT 'EARNINGS REPORT' SELECT ALL CONTROL PAYFILE-DEPTNUM PRINT PAYFILE-DEPTNUM PAYFILE-EMPNUM PAYFILE-NAME PAYFILE-REGEARN (PAYFILE-OVTEARN) END

Following is a line-by-line explanation of the earnings report program.

In the first statement, the USER command is used to provide the first line of heading on each page of the report.
```
 USER 'XYZ COMPANY, INC.'
```
In the second statement, the INPUT command is used to define the file to the Reporting Facility The BLOCK EQ parameter is calculated by multiplying 43 x 50.
```
 PAYFILE:  INPUT DISK BLOCK EQ 2150 FIXED RECORD EQ 43
```

In the third, fourth, and fifth statements, the PAYFILE-DEPTNUM, PAYFILE-EMPNUM, and PAYFILE-NAME fields are defined and assigned column headings.

 DEFINE PAYFILE-DEPTNUM       001-003 X ' DEPT ' 'NUMBER'
 DEFINE PAYFILE-EMPNUM        004-007 X 'EMPLOYEE' ' NUMBER '
 DEFINE PAYFILE-NAME          008-027 X 'EMPLOYEE' '  NAME  '

In the sixth and seventh statements, the PAYFILE-REGEARN and PAYFILE-OVTEARN fields are defined and assigned column headings.
```
 DEFINE PAYFILE-REGEARN    034-038 N2 'REGULAR'  'EARNINGS'
 DEFINE PAYFILE-OVTEARN    039-043 N2 'OVERTIME' 'EARNINGS'
```
Notice the N2 parameter in both of the above statements. N indicates the fields named PAYFILE-REGEARN and PAYFILE-OVTEARN contain zoned decimal data. The number of implied decimal places is indicated by the integer 2.
In the eighth statement, the GET command is used to get a record from PAYFILE.
```
 GET PAYFILE
```
The GET statement following the DEFINE statement is a significant deviation from the previous programs in this guide and requires some explanation.

As previously discussed, the general order of entry for individual statements is as follows:
- Specify a heading with the USER command.
- Define the files with the INPUT command.
- Define the fields with the appropriate DEFINE command format.
- Move data with the MOVE command if accessing a CA Datacom/DB file.
- Start reading the file with the GET command.
- Direct program flow with the GOTO command.
- Manipulate the data with one of the following commands:
```
   COMPUTE              MULTIPLY
   DECODE               DIVIDE
   SET                  MOVE
   ADD                  INCREMENT
   SUBTRACT             DECREMENT
```
- Specify the report with the following commands:
```
   REPORT                CONTROL
   SELECT                PRINT
```
- End the program with the END command.
Note: Since this program accesses a standard file and not a CA Datacom/DB file, no MOVE statements are required.

In this earnings report program, the GET and GOTO statements were not really necessary because the Reporting Facility would have automatically provided those two statements after the DEFINE statements. The system automatically provides GET and GOTO statements for the first file defined. See GET Command for more information about the GET command.

In the two previous programs in this guide, you specified the GET and GOTO statements. If they had not been specified, the Reporting Facility would have automatically generated them following the last DEFINE statement. This would produce undesirable results.

When a GET statement is found that specifies the name of the first file defined, the automatic GET and GOTO statements are not generated.
In the ninth statement, the GOTO command is used to direct the Reporting Facility to the end-of-file procedure when it finishes reading the file. The GOTO statement is not mandatory for this program.
```
 GOTO EOJ PAYFILE EQ 'E'
```
In the tenth statement, the REPORT command is used to specify the second line of heading.
```
 REPORT 'EARNINGS REPORT'
```
In the eleventh statement, the SELECT command is used to indicate which records are to be selected for processing.
```
 SELECT ALL
```
In the twelfth statement, the CONTROL command is used to specify how the report is to be sorted.
```
 CONTROL PAYFILE-DEPTNUM
```
In the thirteenth statement, the PRINT command is used to specify which fields are to appear in the report, the order in which the fields are to be printed, and which fields are to have a total.
```
 PRINT PAYFILE-DEPTNUM PAYFILE-EMPNUM PAYFILE-NAME
               PAYFILE-REGEARN (PAYFILE-OVTEARN)
```
PAYFILE-OVTEARN is enclosed in parentheses. This indicates that the values in the PAYFILE-OVTEARN field are to be accumulated and printed as a final total at the end of the report.
The END command terminates the Reporting Facility program.