Writing a Program (CA Datacom/DB Tables)

CA Datacom/DB Reporting Facility Tutorial › Writing a Program (CA Datacom/DB Tables)

Writing a Program (CA Datacom/DB Tables)

You have now thoroughly examined the sample program and may test your skills by writing a simple CA Datacom/DB Reporting Facility program. This section presents the requirements for a program to test your understanding of the Reporting Facility concepts.

Before writing the program, become familiar with these guidelines for coding input statements.

Although a single statement may exceed one input line, the statements should be on separate lines, if possible, to make the program more readable.
Keywords, commands, field names, numeric constants, and alphanumeric literals may not exceed one input line.
The entries on a particular line of coding may be separated from each other by any number of spaces.
The statements are entered free-form, requiring no coding forms.
When coding a program, remember that the Reporting Facility reads input.
When entering code at a terminal, each line on the screen is considered to be one card.
Only the first 71 positions of each line are available for coding input statements.

Write the program to produce a report in the following format:

XYZ COMPANY, INC. 01 NOV 08 PAYROLL REPORT PAGE 1 DEPT EMPLOYEE EMPLOYEE REGULAR OVERTIME NUMBER NUMBER NAME EARNINGS EARNINGS XXX XXXX XXXXXXXXXXXXXXXXXXXX XXX.XX XXX.XX . . . . . . . . . . . . . . . XXX XXXX XXXXXXXXXXXXXXXXXXXX XXX.XX XXX.XX

This format indicates that the program will generate a report that includes:

Specified headings
Department number
Employee number
Employee name
Regular earnings
Overtime earnings

You will need the following information to write the program:

The accessed file is a CA Datacom/DB table.
The table name is PAY and resides in database 001.
The table is to be sequentially searched, starting with the first record.
All of the fields defined with DEFINE statements are alphanumeric, except for PAYROLL-REGEARN and PAYROLL-OVTEARN, which are zoned decimal.
The key name is IDNUM.
The element name is PAYRC.
The department number field is named PAYROLL-DEPTNUM and occupies positions 1—3 of the element.
The employee number field is named PAYROLL-EMPNUM and occupies positions 4—7 of the element.
The employee name field is named PAYROLL-NAME and occupies positions 8—27 of the element.
The regular earnings field is named PAYROLL-REGEARN and occupies positions 28—32 of the element.
The overtime earnings field is named PAYROLL-OVTEARN and occupies positions 33—37 of the element.
The field to hold the CA Datacom/DB command is named PAYROLL-COMMAND.
The field to hold the CA Datacom/DB key name is named PAYROLL-KEY.
The field to hold the CA Datacom/DB element is named PAYROLL-ELMLIST.
The report is to be sorted in ascending sequence by department number.

After you have written the program, look at the following solution for the correct input statements and an explanation of those statements.

Solution

 USER 'XYZ COMPANY, INC.'
 PAYROLL:  INPUT DATACOM  RECORD EQ 337  NAME EQ PAY DBID EQ 001
 DEFINE PAYROLL-COMMAND  001-005   X
 DEFINE PAYROLL-KEY      006-010   X
 DEFINE PAYROLL-ELMLIST  191-201   X
 DEFINE PAYROLL-DEPTNUM  301-303   X ' DEPT ' 'NUMBER'
 DEFINE PAYROLL-EMPNUM   304-307   X  'EMPLOYEE' 'NUMBER'
 DEFINE PAYROLL-NAME     308-327   X  'NAME'
 DEFINE PAYROLL-REGEARN  328-332  N2 'REGULAR' 'EARNINGS'
 DEFINE PAYROLL-OVTEARN  333-337  N2 'OVERTIME' 'EARNINGS'
 MOVE 'GETIT' TO PAYROLL-COMMAND
 MOVE 'IDNUM' TO PAYROLL-KEY
 MOVE 'PAYRC' TO PAYROLL-ELMLIST
 GET PAYROLL
 GOTO EOJ WHEN PAYROLL EQ 'E'
 REPORT 'PAYROLL REPORT'
 SELECT ALL
 CONTROL PAYROLL-DEPTNUM
 PRINT PAYROLL-DEPTNUM PAYROLL-EMPNUM PAYROLL-NAME
      PAYROLL-REGEARN PAYROLL-OVTEARN
 END

The following is a line-by-line explanation of the above payroll program.

USER Statement

In the first statement, the USER command provides the first line of heading on each page of the report.

 USER 'XYZ COMPANY, INC.'

INPUT Statement

In the second statement, the INPUT command defines the table to the Reporting Facility.

 PAYROLL:  INPUT DATACOM RECORD EQ 337 NAME EQ PAY DBID EQ 001

Communications Area

The next three DEFINE statements make up the Communications Area.

The first DEFINE statement in the Communications Area allocates space for the CA Datacom/DB command.
```
 DEFINE PAYROLL-COMMAND    001-005 X
```
The second DEFINE statement in the Communications Area allocates space for the CA Datacom/DB key name.
```
 DEFINE PAYROLL-KEY      006-010 X
```
The third DEFINE statement in the Communications Area allocates space for the CA Datacom/DB element.
```
 DEFINE PAYROLL-ELMLIST    191-201 X
```

Data Area

The next five DEFINE statements make up the Data Area.

In the first and second DEFINE statements in the Data Area, the PAYROLL-DEPTNUM and PAYROLL-EMPNUM fields are defined and assigned column headings.
```
 DEFINE PAYROLL-DEPTNUM    301-303 X ' DEPT ' 'NUMBER'
 DEFINE PAYROLL-EMPNUM     304-307 X 'EMPLOYEE' ' NUMBER '
```
The third DEFINE statement in the Data Area defines the NAME field.
```
 DEFINE PAYROLL-NAME        308-327   X   'NAME'
```
In the fourth and fifth DEFINE statements in the Data Area, the PAYROLL-REGEARN and PAYROLL-OVTEARN fields are defined and assigned column headings.
```
 DEFINE REGEARN    328-332 N2 'REGULAR' 'EARNINGS'
 DEFINE OVTEARN    333-337 N2 'OVERTIME' 'EARNINGS'
```
Notice the N2 parameter in both of the above statements. N indicates that the fields named PAYROLL-REGEARN and PAYROLL-OVTEARN contain zoned decimal data. The number of implied decimal places is indicated by the integer 2.

Move Statements

The first MOVE statement moves the CA Datacom/DB command GETIT to the PAYROLL-COMMAND field in the Communications Area. GETIT specifies a sequential search of the table.
```
 MOVE 'GETIT' TO PAY-COMMAND
```
The second MOVE command moves the CA Datacom/DB key name IDNUM to the PAYROLL-KEY field in the Communications Area. IDNUM indicates that the table is to be searched by using the employee ID number as the key.
```
 MOVE 'IDNUM' TO PAYROLL-KEY
```
The third MOVE statement moves the CA Datacom/DB element, PAYRC, to the PAYROLL-ELMLIST in the Communications Area.
```
 MOVE 'PAYRC' TO PAYROLL-ELMLIST
```

GET Statement

The GET statement tells the Reporting Facility to return a record from the table named PAYROLL.

 GET PAYROLL

GOTO Statement

The GOTO statement specifies a branch to the end-of-job procedure when the Reporting Facility determines the end of the table.

 GOTO EOJ PAYROLL EQ 'E'

REPORT Statement

The REPORT command specifies that the second heading line on each page of the report is to be PAYROLL REPORT.

 REPORT 'PAYROLL REPORT'

SELECT Statement

The SELECT statement specifies that all the records in the table are to be selected for processing.

 SELECT ALL

CONTROL Statement

The CONTROL statement specifies that the report is to be sorted by department number.

 CONTROL PAYROLL-DEPTNUM

PRINT Statement

The PRINT statement specifies which fields are to be printed and the order in which they are to be printed.

 PRINT PAYROLL-DEPTNUM PAYROLL-EMPNUM PAYROLL-NAME
	PAYROLL-REGEARN PAYROLL-OVTEARN

END Command

The END command signals the Reporting Facility that the last statement has been processed.