Utilities › RMOGRW - General Report Writer › TITLE Control Statement › Example 4

Example 4

The following example, which is located in RMOGRW04 in CAI.CVDEJCL, produces a report containing bundle identifiers, bundle attributes, special instructions, report identifiers, and distribution identifiers. Each bundle identifier appears on a separate page. Report identifiers and distribution identifiers print horizontally.

//EXAMPLE4 JOB  ACCOUNT,PROGRAMMER
//RMOGRW   EXEC PGM=RMOGRW
//STEPLIB  DD   DSN=CAI.CVDELOAD,DISP=SHR
//SYSPRINT DD   SYSOUT=*
//PRTFILE  DD   SYSOUT=*
//SYSIN    DD   *

/CONTROL DATABASE=DELIVER.SYSTEM1
/PRINT PAGE
/TITLE 'BUNDLE DEFINITION FOR '||BID 
/PRINT 'ATTRIBUTES:' SKIP(2)
/PRINT 'BANNER=('||BBANNER1||','||
       BBANNER2||','||
       BBANNER3||')' COL(3)
/PRINT 'DIST='||BDIST COL(3)
/DEFINE I BIN
/DO I = 1 TO NBA BY 1
/   PRINT BA COL(6)
/   NEXT BA
/END

/PRINT 'LATE='||BLATE COL(3)
/PRINT 'INTERVAL='||BINVL COL(3)
/PRINT 'SPECIAL INSTRUCTIONS:' SKIP(2)
/DO I = 1 TO NBINST BY 1
/   PRINT BINST COL(3)
/   NEXT BINST
/END

/DEFINE PCOL BIN
/SET PCOL = 999
/PRINT 'REPORT IDENTIFIERS:' SKIP(2)
/DO I = 1 TO NRID BY 1
/   IF PCOL+32 > LINESIZE-1
/           SET PCOL = 3
/   END
/   PRINT RID COL(PCOL)
/   SET PCOL=PCOL+34
/   NEXT RID
/END

/SET PCOL = 999
/PRINT 'DISTRIBUTION IDENTIFIERS:' SKIP(2)
/DO I = 1 TO NDISTID BY 1
/   IF PCOL+32 > LINESIZE-1
/           SET PCOL = 3
/   END
/   PRINT DISTID COL(PCOL)
/   SET PCOL=PCOL+34
/   NEXT DISTID
/END

/PRINT 'JOB CARDS:' SKIP(2)
/PRINT BJCD1 COL(3)
/PRINT BJCD2 COL(3)
/PRINT BJCD3 COL(3)
/PRINT BJCD4 COL(3)
/END