Coding Each AOF Rule Type › Command Rules › Examples of CMD Rules

Examples of CMD Rules

• Example 1: This example show how to have a CMD rule secure that only JES2 initiator control commands ($TIx) can be issued from the current sysplex master console:

  )CMD $T
  )PROC
  /* Attempting to fire on a JES2 command means we must have a */
  /* specifier of the JES2 command character (normally $)      */
  /* followed by the first letter of the desired command       */
  /* (T FOR TIxxx). Since many JES2 commands begin with a 'T'  */
  /* (For example: $TIXXX,TPRTXXX) we must check the           */
  /* environmental variable CMD.TEXT to see the exact text of  */
  /* the command that was entered. Leave the rule if this      */
  /* is not a JES2 initiator control command. SSICMD parm must */
  /* be set to YES for JES2 CMD control.                       */
  
  if SUBSTR(CMD.TEXT,1,3) ¬= '$TI' then
    return
  
  /* Use the OPS/REXX OPSINFO function to get current sysplex  */
  /* master console value, then compare this value to the      */
  /* value of the console that issued the command which is     */
  /* contained in the CMD.CONSNAME event variable. If this     */
  /* is not the sysplex master, we'll send a message back to   */
  /* console and null out the command so JES2 won't see it.    */
  
  PLEXMSTR= OPSINFO('MSTCONSNM')
  if CMD.CONSNAME ¬= PLEXMSTR then
    do
      msgtxt = 'JES2 init control not allowed from this console'
      ADDRESS WTO
      "MSGID(OPSMVS01) TEXT('"msgtxt"') HILITE",
      "CNNAME("CMD.CONSNAME")"
      CMD.TEXT = ''
      return 'ACCEPT'
    end
  else
    return                                  /* OK to issue */  
  

• Example 2: This example shows how to use a pseudo command rule to cycle a VTAM node:

  )CMD VNET
  )PROC
  /* The purpose of this pseudo CMD rule is to give operators  */
  /* or anyone wanting to cycle any VTAM node, a tool to       */
  /* facilitate the issuing of the V NET,INACT and V NET,ACT   */
  /* commands with one command. From any console you simply    */
  /* enter 'VNET nodeid' and the logic of this rule will simply*/
  /* issue a V NET,INACT and then a V NET,ACT command to the   */
  /* extracted nodeid using the console that invoke the pseudo */
  /* command so that the command responses get routed back.    */
  
  NODEID= WORD(CMD.TEXT,2)         /* get the passed node id   */
  ADDRESS OPER                     /* Issue vtam command .     */
  "COMMAND(V NET,INACT,ID="NODEID",F) CONNAME("CMD.CONSNAME")"
  "COMMAND(V NET,ACT,ID="NODEID",SCOPE=ALL) CONNAME("CMD.CONSNAME")"
  return 'ACCEPT'                  /* z/OS won't see pseudo cmd */