AOF Rule Tools › AOF Variables › Event-related Variables

Event-related Variables

Event-related variables are compound symbols that begin with a reserved stem of GLVEVENT. They let you share data between different AOF rules that are processing the same event. In a case where you allow different groups (for example, operations, CICS, IMS) to have their own rule sets, there may be a need to coordinate a process between two or more rules that execute on the same event. Event-related variables have a life span of the event.

Example: Sharing Data Between AOF Rules

• Rule # 1: This first rule resides in the CICSGRP rule set

  )MSG $HASP100
  )PROC
  /*************************************************************/
  /* Rule Purpose :  Set a event-related variable to flag that */
  /*          the CICSGRP wants to currently request that      */
  /*          $HASP100 messages from CICSx jobs get            */
  /*          suppressed and deleted from SYSLOG               */
  /* $HASP100 CICSxxx ON INTRDR                                */
  /*************************************************************/
  JOB = WORD(MSG.TEXT,2)             /* get 2nd word of message */
  if SUBSTR(JOB,1,4) <> 'CICS' then  /* not CICSx              */
    return 
  GLVEVENT.DISP = 'DELETE'
  

• Rule #2: This second rule resides in the IMSGRP rule set

  )MSG $HASP100
  )PROC
  /*************************************************************/
  /* Rule Purpose :  Set a event-related variable to flag that */
  /*          the IMSGRP wants to currently request that       */
  /*          $HASP100 messages from IMSx jobs get             */
  /*          suppressed.                                      */
  /* $HASP100 IMSxxx ON INTRDR                                 */
  /*************************************************************/
  JOB = WORD(MSG.TEXT,2)             /* get 2nd word of message */
  if SUBSTR(JOB,1,3) <> 'IMS' then   /* not IMSx               */
    return
  

  GLVEVENT.DISP = 'SUPPRESS'
  

• Rule #3: This third rule resides in the OPERATNS rule set

  )MSG $HASP*
  )PROC
  /**************************************************************/
  /* Rule Purpose :  Operations makes the final call on message */
  /*          disposition based on the value of a event-related */
  /*          variable that different groups can override       */
  /*          at their request. Assume disposition is           */
  /*          NORMAL if a group hasn't set the variable         */
  /**************************************************************/
  if OPSVALUE('GLVEVENT.DISP','E') = 'N' then 
    DISP = 'NORMAL'
  else
    DISP = GLVEVENT.DISP
  

  return DISP
  

Rule #1 and Rule #2 execute on a specific $HASP100 event and will execute before Rule #3 because it is a more generic message specification of $HASP*. They will set the event-related variable GLVEVENT.DISP accordingly. Rule #3 will then interrogate this variable to determine what action to take.

Review the following additional facts about event-related variables:

• Event-related variables are used only in the )PROC section of a rule and are unique to rules that execute on the same event.
• They are automatically deleted by CA OPS/MVS when the last rule executing on the event completes.
• An event-related variable must begin with a stem of GLVEVENT.
• The name can be up to 78 characters in length including the stem of GLVEVENT.
• The value can be up to 32,000 bytes.

More information:

Building and Controlling AOF Rules