AOF Rule Tools › AOF Variables › Address Space-related Variables

Address Space-related Variables

Address space-related variables are compound symbols that begin with a reserved stem of GLVJOBID. They let you share data between different AOF rules for events that originate from the same address space. This lets you save data generated during one event created by a job, and then use that data in another event created by the same job.

For example, consider the following two AOF rules:

• Rule #1

  )MSG $HASP375
  )PROC
  /*****************************************************************/
  /* Rule Purpose : Set a local variable to keep track of the most */
  /*                current # of lines exceeded during run time    */
  /*                This variable will be checked when the job     */
  /*                ending event occurs.                           */
  /* $HASP375 jobname ESTIMATE EXCEEDED BY # LINES                 */
  /*****************************************************************/
  if WORD(MSG.TEXT,5) < > 'BY' then
    return
  GLVJOBID.EXCEEDED = WORD(MSG.TEXT,6)  /* # of lines              */
  

• Rule #2

  )EOJ *
  )PROC
  /*****************************************************************/
  /* Rule Purpose : Check to see if the batch job that just ended  */
  /*                exceeded any output lines during its run time  */
  /*                by testing to see if the GLVJOBID variable     */
  /*                that would have been set in the $HASP375       */
  /*                rule exists. Log info if variable is present.  */
  /*  EOJ fires automatically when job terminates.                 */
  /*****************************************************************/
  if OPSVALUE('GLVJOBID.EXCEEDED','E') = 'N' then
    return
  JOB = EOJ.JOBNAME
  NUMLINES = GLVJOBID.EXCEEDED
  MSG = 'OPSAUTO1 BATCH JOB ' JOB' LAST EXCEED ='NUMLINES
  LOGIT = OPSSEND('*','B',MSG)
  

Suppose that JOB1 and JOB2 start on the system at the same time. JOB1 begins to exceed expected output lines and the JOB1 address space produces a $HASP375 message. This event executes Rule #1, which sets a unique GLVJOBID.EXCEEDED variable for JOB1 only. Both JOB1 and JOB2 end at the same time, thus executing Rule #2.

While Rule #2 is processing the end-of-job event caused by JOB1 ending, the local variable GLVJOBID exists, and the rule produces the informational message in the OPSLOG that includes the value of the GLVJOBID.EXCEEDED address space-related variable that was set in Rule #1. While Rule #2 is processing the end-of-job event caused by JOB2, the local variable GLVJOBID.EXCEEDED does not exist, so no further processing is done in the rule.

Review the following additional facts about address space-related variables:

• Address space-related variables are used only in the )PROC section of a rule and are unique to the address space that triggered the rule.
• They are automatically deleted by CA OPS/MVS when the address space or batch job associated with it terminates. Batch jobs are handled differently than other address spaces. The address space-related variables associated with a batch job are deleted when the batch job ends, even though the initiator address space in which it ran remains active and may subsequently execute other batch jobs.
• An address space-related variable name must begin with a stem of GLVJOBID.
• The name can be up to 78 characters in length including the stem of GLVJOBID.
• The value can be up to 32,000 bytes.
• Some messages appear to be issued from a particular job but are actually issued on behalf of another address space. For example, the $HASP100 message that indicates a job is on the internal reader is actually issued from the JES2 address space and not the address space of the job. Use the OPSLOG JOBNAME and ASID columns to verify that the message is being issued from unique address spaces prior to selecting a GLVJOBID variable.