|
|
|
There are sample CA Earl and CA Easytrieve reports that will process the Datacom Interface EXTDATA records.
Note: The EXTDATA record layout is described in the chapter "EXTDATA Reporting" in the User Guide.
OPTION LIST OFF
NOTE ******************************************************************
NOTE * REPORT ID: ERXTD001 *
NOTE * REPORT NAME: DATACOM PROCESS REPORT *
NOTE * *
NOTE * DESCRIPTION: THIS WILL REPORT ON THE TOTAL NUMBER OF IOS *
NOTE * AMOUNT OF CPU TIME CONSUMED BY EACH INDIVIDUAL*
NOTE * RUN UNIT ACCESSING DATACOM, SORTED BY JOB NAME*
NOTE * AND ACCOUNTING INFORMATION. *
NOTE * *
NOTE * RECORD TYPES: MRXTHDR, *
NOTE * MRXTSIED *
NOTE * *
NOTE * EXTDATA RECORD: SIED *
NOTE * *
NOTE * MACROS: *
NOTE ******************************************************************
OPTION PRINTER = 132
OPTION PAGE = 60
OPTION PRECISION = ALL
OPTION CPAGE = 60
HISTIN: FILE JARS RECORD=3697
DEF INAREA 1-3697 X
COPY MRXTHDR
COPY MRXTSIED
DEF SESSDATE =RECDATE 1-6 N 'SESSION' 'DATE' PIC '99/99/99'
DEF SESSTIME =RECTIME 1-6 N 'SESSION' 'TIME' PIC '99:99:99'
NOTE ******************************************************************
NOTE * SELECTING FROM HISTORY FILE EXTDATA, SPECIFICALLY SIED *
NOTE ******************************************************************
!
IF PROCID NOT = ':' OR
EXTTYPE NOT = 'SIED'
THEN GOTO START
ENDIF
!
NOTE ******************************************************************
NOTE * REPORT PROCESSING SECTION *
NOTE ******************************************************************
!
REPORT 'DATACOM ACTIVITY SUMMARY'
TITLE ' '
TITLE @1 'REPORT ID: ERXTD001' @54 'SYSTEM ID:' SID
TITLE @1 'SOURCE : DATACOM ACCT' @54 ' APPL JOB:' EXTSIED_CALLER_JOB
TITLE @54 ' USER ID:' EXTSIED_USER_INFO
TITLE @54 ' ACCOUNT:' EXTSIED_ACCOUNTING
TITLE ' '
!
CONTROL (EXTSIED_CALLER_JOB) (EXTSIED_USER_INFO)
(EXTSIED_ACCOUNTING) SKIP
EXTSIED_RUN_UNIT
!
PRINT
@1 ' '
EXTSIED_RUN_UNIT
SESSDATE
SESSTIME
EXTSIED_ELAPSED_TIME
EXTSIED_RUNNING_TIME
EXTSIED_TOTAL_IOS
END
LIST OFF
******************************************************************
* REPORT ID: EZXTD001 *
* REPORT NAME: DATACOM ACTIVITY SUMMARY *
* DESCRIPTION: THIS SUMMARY REPORT WILL SHOW RESOURCE *
* CONSUMPTION WITHIN DATACOM SUMMARIZED ON *
* JOBNAME, RUN UNIT AND OPERATOR ID. *
* *
* RECORD TYPES: MZXTHDR, *
* MZXTSIED *
* *
* EXTDATA RECORD: SIED *
* *
******************************************************************
PARM ABEXIT (SNAP) DEBUG (FLDCHK STATE)
FILE EXTDATA
%MZXTHDR
%MZXTSIED
*
JOB INPUT EXTDATA
IF PROCID = ':' AND EXTTYPE = 'SIED'
GOTO PROCESS_DATA
ELSE
GOTO JOB
END-IF
PROCESS_DATA
*
PRINT REPORT1
*
REPORT REPORT1 SUMMARY SPACE 0 PAGESIZE (60 60) LINESIZE 132 NOADJUST +
SUMCTL DTLCOPY
*
SEQUENCE EXTSIED_CALLER_JOB EXTSIED_USER_INFO EXTSIED_ACCOUNTING +
EXTSIED_RUN_UNIT
*
CONTROL EXTSIED_CALLER_JOB EXTSIED_USER_INFO EXTSIED_ACCOUNTING +
NEWPAGE EXTSIED_RUN_UNIT
*
TITLE 01 COL 51 'DATACOM ACTIVITY SUMMARY'
TITLE 02 ' '
TITLE 03 COL 1 'REPORT ID: EZXTD001' COL 54 'SYSTEM ID ' SID
TITLE 04 COL 1 'SOURCE : DATACOM' COL 54 'APPL JOB ' +
EXTSIED_CALLER_JOB
TITLE 05 COL 54 'USER ID ' +
EXTSIED_USER_INFO
TITLE 06 COL 54 'ACCOUNT ' +
EXTSIED_ACCOUNTING
LINE EXTSIED_RUN_UNIT ' ' +
RECDATE ' ' +
RECTIME ' ' +
EXTSIED_ELAPSED_TIME ' ' +
EXTSIED_RUNNING_TIME ' ' +
EXTSIED_TOTAL_IOS
The sample output will look like this:
121/01/04 DATACOM ACTIVITY SUMMARY REPORT ID: ERXTD001 SYSTEM ID: XE96 SOURCE : DATACOM ACCT APPL JOB: CHARLIEB USER ID: DATSTART ACCOUNT: OTHERS ------------------------------------------------------------------------------------------------------------------------------- RUN SESSION SESSION ELAPSED RUNNING TOTAL UNIT DATE TIME TIME (MIN) TIME (MIN) IOS ------------------------------------------------------------------------------------------------------------------------------- 00025103 03/12/05 09:49:42 0.25160 0.12551 735 00025104 03/12/05 09:50:05 0.15488 0.05872 1658 00025105 03/12/05 09:50:15 0.06874 0.02411 778 00025106 03/12/05 09:50:20 0.06346 0.01411 1256 00025107 03/12/05 09:50:26 0.07104 0.01463 903
| Copyright © 2012 CA. All rights reserved. |
|