実装ガイド › ケース スタディ例 › ビジネス ロジック スクリプティングの例 › ケース スタディ 12： カウンタ ロジックの障害数の計算への使用

ケース スタディ 12： カウンタ ロジックの障害数の計算への使用

以下の例では、所定の計算期間内に発生した障害の数を計算します。 この式とその実装に使用された方法は、何かを計算する際には常に必要になる公式の例と考えることができます。

計算には以下の仮定が使用されてます。

• 入力イベント
  • 可用性イベント、ステータス（0/1）
  • 可用性イベントは数分おきに到着します。 イベントの頻度は予測できず（5 分ごとに発生する場合もあれば 1 時間に 1 度発生する場合もあります）、また不要なイベントが発生する場合もあります（0、0、0、1、1、0 など）。
• 時間帯 - 就業時間帯。この時間帯外に発生した障害はカウントされません。
• 必要な結果は、期間中に発生した障害数です。

計算期間中に発生した障害を集計するには、周期的なカウンタ変数とシステム状態を格納する変数を保存する必要があります。 不要なイベント情報を受信する場合もある（つまり、'Up' イベントのすぐ後に別の 'Up' イベントが続く）ので、システム状態が 'Up' から 'Down' に変化した場所の数をカウントし、毎回 'Down' イベントが受信されたときは、すでにカウント済みの障害を表している場合があるのでカウントしないことも必要です。

以下は、カウント システムの稼動時間と休止時間をカウントするシステムを図示したものです。

考慮する必要のある重要なポイント

• 定数 - コード中で定数値を使用するのではなく、定数定義を使用することが推奨されます。 このようにして、値を変更する必要がある場合は、定数定義のみで変更するのが簡単で、コード中を探し回る必要がありません。 さらに、必要に応じてパラメータ使用に変更するのは簡単です。 上記の例では、イベントで受信されたシステム状態を示す値は、コードを理解しやすくするため、また、システム状態を表すのではなくカウント目的で数字のゼロが使用されるときと区別するために、定数として定義されています。
• グローバル変数
  • カウンタ - カウンタ変数の定義はグローバル定義です。 式では、コードの先頭、かつサブルーチンまたは関数の外側で宣言されています。 この場合、カウンタ変数をグローバル変数として定義することは重要です。 これにより、コード内の複数のサブルーチン/関数中で使用できるようになり、また、計算期間中その値を保持し、期間の最後にその結果を提供することが可能になります。

    この例では、カウンタ変数はコード中の 3 か所で使用される必要があります。

    • 期間の初めに初期化されること。
    • イベント ハンドラ内の失敗したイベントの場合には進められる必要があること。
    • 期間の最後に結果関数によって出力されること。
  • システムの前の状態 - この変数にはシステムの状態が保持され、システム状態を備えた新しいイベントが受信されるたびに更新されます。 この変数は、コード中の次のようなサブルーチン/関数でも使用されていることからもグローバルである必要があります。
    • 計算の最初に初期化されること。
    • 新規イベントが受信されるときに更新されること。
• 時間帯に関する考慮事項 - 障害が発生したのが時間帯の期間内かどうかを確認するために context.IsWithinTimeSlot プロパティの値を使用できます。 コンテキストは、コード内のどこからでも使用できるグローバル オブジェクトで、この場合、いつ障害が受信され、それが時間帯の期間内か期間外かを示すのに使用されます。 イベントのタイムスタンプでそのフラグが TRUE を返す場合、イベントは時間帯の期間内に発生していますが、FALSE を返す場合、イベントは時間帯の外で発生したことを示します。 必要なロジックによれば、時間帯の外で発生する障害は無視され、カウントされません。
• 変数の初期化
  • カウンタ変数 - 周期的な値を保持し、したがって OnPeriodstart ハンドラ内で初期化され、計算期間ごとに障害を別々に数えることを保証します。 各期間はゼロで開始され、この期間内の障害数のみを出力します。

    期間ごとの累積障害を計算する必要がある場合（つまり、各期間の結果はこの期間の最後までに発生した障害すべてで、それまでの全期間を含んでいる場合）、カウンタを OnLoad ハンドラ内でのみ初期化し、OnPeriodStart ハンドラから削除する必要があります。 したがって、カウンタは数え続け、以下に示すように期間の間に累積を続けます。

    Sub OnLoad(time)
        FingerprInted=0
    End Sub
    

  • システム状態変数 - 計算の最初に一度初期化する必要があり、その点以降、ステータス イベントごとに更新される必要があります。 この変数は計算の全体にわたってその値を保持し、一定の計算期間に制限されません。 また、それは、計算期間の間のその値を保持する必要があります。 最初のイベントを受信する前のシステム状態が不明なので、システムの状態についてはある仮定をする必要があります。 一般的な仮定は、システムは "稼動中" であるということです。 この仮定は合意される必要があり、以下につながる可能性があるのでチェックされる必要があります。

    計算が開始し、システムの状態が実際は '休止' で、最初のイベントがこの '休止' 状態を示すために到着した場合、想定された状態は "稼動" なので、これは障害に数えられます。 この障害は、その期間中に必ずしも発生しなかったとしても、最初の計算に対して数えられます。

    Option Explicit
    
    'Constants definitions
    Const UP=1
    Const DOWN=0
    
    'Global variable for counting failures
    Dim FingerprInted
    Dim SystemStatus
    
    Sub OnRegistration(dispatcher)
       ' The parameters of the method are: <procedure name>, <Event Type>
       dispatcher.RegisterByContractPartyAndService "OnAvailabilityEvent","AvailabilityEvent"
    End Sub
    
    Sub OnLoad(time)
       SystemStatus = UP 'assume the first system status
    End Sub
    
    Sub OnPeriodStart(time)
       FingerprInted = 0
    End Sub
    
    Sub OnAvailabilityEvent(eventDetails)
       ' In case it's a failure and within the timeslot then it is counted
       If context.IsWithinTimeSlot and SystemStatus=UP and _
             eventDetails("Status")=DOWN Then
          FingerprInted = FingerprInted + 1
       End If
       ' update the system status for next comparison
       SystemStatus = eventDetails("Status") 
    End Sub
    
    Function Result
       Result = FingerprInted
    End Function