Erstellen von Datenträgern und Volumes mithilfe des DiskPart-Befehls

Folgende Beispiele zeigen, wie Basisdatenträger und dynamische Datenträger mithilfe des DiskPart-Befehls erstellt werden.

Beispiel 1: Erstellen von Basisdatenträgern mithilfe des DiskPart-Befehls.

Wählen Sie einen Datenträger aus, unabhängig davon, ob es sich um einen rohen Datenträger oder um einen dynamischen Datenträger handelt, und konvertieren Sie ihn in einen einfachen Speichertyp.
```
X:\windows\system32\DR>diskpart
```
Anzeigen der vorhandenen Datenträger.
```
DISKPART>list disk
```
```
DISKPART>list volume
```
Erstellen des Start- und Systemvolumes auf Datenträger 0
```
DISKPART>select disk 0
```
(Optional) Bei Bedarf in GPT-Stil konvertieren
```
DISKPART>convert gpt
```
Erstellen von Basisvolumes für das System- und Startvolume.
Erstellen des Systemvolumes
```
DISKPART>create partition primary size=100
```
Erstellen des Startvolumes
```
DISKPART>create partition primary
```
```
DISKPART> list volume
```
Systempartition als aktiv markieren.
```
DISKPART>list partition
```
```
DISKPART>select partition 1
```
```
DISKPART>active
```
Überprüfen des Status des Systemvolumes.
```
DISKPART> detail partition.
```
Hinweis: Verwenden Sie aktive Befehle nur für die Systempartition.

(Optional) Dem Volume einen Laufwerksbuchstaben zuweisen und formatieren.

DISKPART>list volume

DISKPART>select volume 2

DISKPART>assign letter=C

DISKPART>format quick

Beispiel 2: Erstellen eines dynamischen System- und Startvolumes mithilfe des DiskPart-Befehls.

Wählen Sie einen Datenträger aus, unabhängig davon, ob es sich um einen rohen Datenträger oder um einen Basisdatenträger handelt, und konvertieren Sie ihn in einen dynamischen Speichertyp.
```
X:\windows\system32\DR>diskpart
```
Anzeigen der vorhandenen Datenträger.
```
DISKPART>list disk
```
```
DISKPART>list volume
```
Erstellen des Start- und Systemvolumes auf Datenträger 0.
```
DISKPART>select disk 0	
```
(Optional) Bei Bedarf in GPT-Stil konvertieren.
```
DISKPART>convert gpt
```
```
DISKPART>convert dynamic	
```
Erstellen von einfachen dynamischen Volumes für das System- und Startvolume.
Erstellen eines Systemvolumes.
```
DISKPART>create volume simple size=100	
```
Erstellen eines Startvolumes.
```
DISKPART> create volume simple			
```
Anzeigen der erstellten Volumes.
```
DISKPART> list volume
```
Vorbereiten von Volume 0 als Systemvolume.
```
DISKPART>select volume 0	
```
```
DISKPART>retain
```
Vorbereiten von Volume 1 als Startvolume.
```
DISKPART>select volume 1
```
```
DISKPART>retain		
```
```
DISKPART> select disk 0
```
(Optional) Systempartition als aktiv markieren.
Anzeigen der Partitionen.
```
DISKPART>list partition
```
```
DISKPART>select partition 2
```
```
DISKPART>active		
```
Überprüfen des Status des Systemvolumes.
```
DISKPART> detail partition	
```
(Optional) Dem Volume einen Laufwerksbuchstaben zuweisen und formatieren.
```
DISKPART>list volume
```
```
DISKPART>select volume 1
```
```
DISKPART>assign letter=C
```
```
X:\windows\system32\DR>format C: /q
```
Hinweis: Wenn Sie eine UEFI-Systempartition erstellt haben, müssen Sie es in ein FAT32-Dateisystem formatieren, bevor Sie Daten wiederherstellen können. Sie müssen den retain-Befehl nicht ausführen.

Beispiel 3: Erstellen eines systemfremden Volumes/Startdatenträger-Volumes mithilfe des DiskPart-Befehls.

Auswählen von Datenträgern und Konvertieren in einen dynamischen Speichertyp.

X:\windows\system32\DR>diskpart

Anzeigen der aktuellen Datenträger und Volumes.

DISKPART>list disk

DISKPART>list volume

Konvertieren aller Datenträger in dynamische Datenträger, mit Ausnahme von Datenträger 0.

DISKPART>select disk 1

DISKPART>convert dynamic

DISKPART>select disk 2

DISKPART>convert dynamic

DISKPART>select disk 3

DISKPART>convert dynamic

Erstellen von RAID-5-Volumes auf jedem Datenträger. Ebenso können Sie einfache, Striped- oder dynamische Datenträgertypen erstellen.
```
create volume raid disk=1,2,3
```

(Optional) Dem Volume einen Laufwerksbuchstaben zuweisen und formatieren.

DISKPART>list volume

DISKPART>assign letter=E

X:\windows\system32\DR>format E: /q

Beispiel 4: Erstellen von UEFI-Systemvolumes und Startvolumes

Wählen Sie Datenträger aus, und führen Sie eine Konvertierung in den GPT-Typ durch.
```
X:\windows\system32\DR>diskpart
```
Anzeigen der vorhandenen Datenträger.
```
DISKPART>list disk
```
```
DISKPART>select disk 0	
```
Um eine UEFI-Partition zu erstellen, müssen Datenträger zunächst in den GPT-Typ konvertiert werden.
```
DISKPART>convert gpt
```

Erstellen Sie die UEFI-Systempartition.

Erstellen Sie die UEFI-Partition.

DISKPART>create partition efi size=100

Erstellen Sie die MSR-Partition.

DISKPART> create partition msr size=128

Erstellen Sie die primäre Partition.

DISKPART> create partition primary

DISKPART>convert dynamic

DISKPART>list volume

Befehl "DiskPart" mithilfe des Arguments "Convert Dynamic".

Behalten Sie das Startvolume bei.

DISKPART>select volume 1

DISKPART>assign letter=C

DISKPART>retain

(Optional) Formatieren Sie das Systemvolume in FAT32.
Vorbereiten von Volume 2 als Systemvolume.
```
DISKPART>select volume 2
```
```
DISKPART>format fs=fat32 quick
```
```
DISKPART>list partition
```
Hinweis: Sie müssen nur das Startvolume beibehalten. Um Daten auf der UEFI-Partition wiederherzustellen, sollte der Masterserver UEFI-partitioniert sein.

Beispiel 5: Erstellen von gespiegelten Systemvolumes und Startvolumes.: Folgende Schritte beschreiben, wie gespiegelte Datenträger auf UEFI-Volume erstellen werden. Weitere Informationen zu gespiegelten Datenträger auf dem UEFI-Volume finden Sie in der Microsoft-Dokument in dieser Verknüpfung: http://support.microsoft.com/kb/951985

Wählen Sie Datenträger 0 aus, und erstellen Sie das primäre UEFI-Start-/Systemvolume.

DISKPART>list disk

DISKPART>select disk 0

DISKPART>convert gpt

DISKPART>create partition efi size=100

DISKPART> create partition msr size=128

DISKPART> create partition primary

DISKPART>convert dynamic

DISKPART>list volume

DISKPART>select volume 1

DISKPART>assign letter=C

Wählen Sie Datenträger 4 als sekundären Datenträger aus, um Start-/Systemvolumes zu erstellen.

DISKPART>list disk

DISKPART>select disk 4

DISKPART>convert gpt

DISKPART>list partition

(Optional: Vorhandene Partition löschen) Wählen Sie Partition 1 auf Datenträger 4 aus, und löschen Sie sie dann mit dem Überschreibungsbefehl.

DISKPART> Select partition 1

DISKPART> Delete partition override

DISKPART>create partition efi size=100

DISKPART> create partition msr size=128

DISKPART>list partition

DISKPART>convert dynamic

Erstellen Sie eine Spiegelung vom Startvolume zum sekundären Laufwerk.
```
DISKPART>select volume C
```
```
DISKPART>add disk=4
```
```
DISKPART>retain
```
(Optional) Formatieren Sie das Systemvolume mit FAT32.
```
DISKPART>list volume
```
```
DISKPART> select volume 1
```
```
DISKPART> format fs=fat32 quick
```
```
DISKPART> select volume 2
```
```
DISKPART> format fs=fat32 quick
```
Hinweis: Erstellen Sie eine Spiegelung auf dem Startvolume, und behalten Sie dieses Volume bei. Sie können nur eine Master-UEFI-Systempartition wiederherstellen.

Weitere Informationen zum DiskPart-Befehl finden Sie in der Microsoft-Dokumentation.