Coding Each AOF Rule Type › Time-of-Day Rules › Examples: Complete TOD Rules

Examples: Complete TOD Rules

• Example 1:

  )TOD 02:00,,,,,CATCHUPYES
  )PROC                                                       
  /*********************************************************/ 
  /* This TOD rule will fire 2 AM every day to simply      */ 
  /* set up the initiators to handle the backup period.    */ 
  /*********************************************************/ 
                                                              
  /*********************************************************/ 
  /* Send information message to sysplex master console    */ 
  /* to indicate that we are configuring initiators using  */ 
  /* the OPS/REXX ADDRESS WTO host environment. Use the    */ 
  /* OPS/REXX OPSINFO function to obtain the name of the   */
  /* sysplex master console.                               */  
  /*********************************************************/ 
  CONSOLE=OPSINFO('MSTCONSNM')    /* GET CURRENT PLEX MSTR */ 
  address WTO                                                 
  "MSGID(OPSAUTO5) TEXT('INITS CONFIGURED FOR BACKUPS')",     
     "CNNAME("CONSOLE")"
  /*********************************************************/
  /* Issue commands to set initiators using OPS/REXX       */ 
  /* ADDRESS OPER host command environment.                */
  
  /*********************************************************/ 
  address OPER 
  "COMMAND($TI1-10,ABC) NOOUTPUT" 
  "COMMAND($TI11-20,EFG) NOOUTPUT"
  

• Example 2: The following two rules demonstrate how to use dynamic TOD rules to initiate a programmatic action at a time after an event occurs. The first rule creates the TOD rule and the second rule deletes the dynamic TOD rule.

  For details about the logic, see the comments in the rules.

  )MSG DFHPA1108
  )PROC 
  /**************************************************************/
  /* This rule will fire on a very early CICS initialization    */
  /* message and simply create a dynamic TOD rule to fire 30    */
  /* minutes from now. The JOBNAME of this CICS region will     */
  /* be used as the name of the TOD rule allowing these monitor */
  /* rules to perform this check for all CICS regions. the logic*/
  /* of the TOD rule is to simply issue a notification message  */
  /* to the local master console that indicates that a CICS did */
  /* not initialize. This TOD rule will be deleted on the       */
  /* initialization message, meaning that the region is OK and  */
  /* thus no message will be issued.                            */
  /* DFHPA1108  A04IC4SL DFHSIT6$ HAS BEEN LOADED.              */
  /**************************************************************/
  REGION = MSG.JOBNAME        /* GET THE REGION NAME OF MESSAGE */
  /* Queue the text of the dynamic TOD rule to the EDQ          */
  
  queue ")TOD *+30 MINS " 
  queue ")PROC" 
  queue "CONSOLE=OPSINFO('LOCMSTCONSNM')" 
  queue "address WTO" 
  queue "'MSGID(ALERT:) TEXT(''CICS "REGION" HAS NOT INITIALIZED'')',"
  queue "'CNNAME('CONSOLE') DESC(2)'" 
  /* ENABLE THE DYNAMIC TOD RULE WITH NAME OF THE REGION        */
  address AOF "ENABLE *DYNAMIC."REGION 
  
  
  )MSG DFHSI1517 
  )PROC          
  /**************************************************************/
  /* This rule will delete dynamic TOD rule that was ENABLEd for*/ 
  /* this region during startup, thus indicating all is well.   */  
  /*   DFHSI1517 A04IC4S1 Control is being given to CICS.       */ 
  /**************************************************************/ 
  REGION = MSG.JOBNAME        /* GET THE REGION NAME OF MESSAGE */ 
  MSG.TEXT=TRANSLATE(MSG.TEXT)  /* UPPER CASE THE MESSAGE       */ 
  /* VERIFY THAT THIS REALLY IS THE CONTROL GIVEN TO MESSAGE    */ 
  if POS('CONTROL IS BEING GIVEN TO CICS',MSG.TEXT) > 0 then
  address AOF "DISABLE *DYNAMIC."REGION